****  Stata do file for meta analysis of exercise for depression data **********

/*

See http://www.gllamm.org/bayes.html

Reference:
Chung, Y., Rabe-Hesketh, S. and Choi, I.-H. (2013). Avoiding zero between-study 
variance estimates in random-effects meta-analysis. Statistics in Medicine 32, 
4071-4089.

*/

* Install software (if needed)
ssc install gllamm, replace  
* download init_prior and calc_prior from http://www.gllamm.org/bayes.html
ssc install metaan, replace
ssc install metareg, replace

* Load data (from http://www.gllamm.org/bayes.html)
use exercise, clear

*** Meta-analysis without covariates

* ML
metaan smd sesmd, ml

* REML
metaan smd sesmd, reml

* BM
eq het: sesmd
constr def 1 [s1]sesmd=1
gllamm smd, i(id) s(het) nats constr(1) adapt prior(gamma, scale(10000) shape(2)) 

*** Meta-regression

* mean-center duration
qui summ duration
generate cduration = duration - r(mean)

* REML
metareg smd abstract cduration, wsse(sesmd) reml

* ML
eq het: sesmd
constr def 1 [s1]sesmd=1
gllamm smd abstract cduration, i(id) s(het) nats constr(1) adapt 

* BM
eq het: sesmd
constr def 1 [s1]sesmd=1
gllamm smd abstract cduration, i(id) s(het) nats constr(1) adapt ///
   prior(gamma, scale(10000) shape(2))