capture log close
log using aggression, replace text
set more off
insheet using aggression.dat, clear
list person gender anger y i1-i12 in 1/12, clean
list person gender anger y i13-i24 in 13/24, clean

recode y 2=1

*** Section 2.3.2: Rasch model
gllamm y i1-i24, nocons i(person) link(logit) family(binom) adapt nip(5)

 * EAP and standard errors
gllapred score, u
sort person
list person scorem1 scores1 if i1==1&person<21, clean

*** Section 2.4.2: Latent regression Rasch model
matrix a=e(b)
eq f1: anger gender
gllamm y i1-i24, nocons i(person) link(logit) family(binom) geqs(f1) from(a) adapt nip(5)

 * EAP with and without effect of person properties
gllapred a, fac
gllapred b, u
sort person
list person am1 bm1 if i1==1&person<21, clean

*** Section 2.5.2 Linear logistic test model (LLTM) 

 * create item predictors:
bysort person (i1-i24): gen item=25-_n

gen do_want = cond(item>12,1,0)
gen other_self = cond(item<7|(item>12&item<19),1,0)
gen blame = cond(mod(item,3)==0,-1,0.5)
gen express = cond(mod(item,3)==2,-1,0.5)

gllamm y do_want other_self blame express, i(person) link(logit) family(binom) adapt nip(5)

*** Section 2.6.2 Latent regression LLTM
matrix a=e(b)
eq f1: anger gender
gllamm y do_want other_self blame express, i(person) link(logit) family(binom) geqs(f1) from(a) adapt nip(5)

log close
exit